You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
73 lines
2.3 KiB
Bash
73 lines
2.3 KiB
Bash
# Maintainer: Brett Cornwall <ainola@archlinux.org>
|
|
# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
|
|
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
|
|
|
|
pkgname=sway
|
|
pkgver=1.6.1
|
|
epoch=1
|
|
pkgrel=2
|
|
pkgdesc='Tiling Wayland compositor and replacement for the i3 window manager'
|
|
arch=(x86_64)
|
|
url='https://swaywm.org/'
|
|
license=(MIT)
|
|
depends=(
|
|
'cairo'
|
|
'gdk-pixbuf2'
|
|
'json-c'
|
|
'pango'
|
|
'polkit'
|
|
'pcre'
|
|
'swaybg'
|
|
'ttf-font'
|
|
'wlroots'
|
|
)
|
|
makedepends=(git meson ninja scdoc setconf wayland-protocols)
|
|
backup=(etc/sway/config)
|
|
optdepends=(
|
|
'alacritty: Terminal emulator used by the default config'
|
|
'dmenu: Application launcher'
|
|
'grim: Screenshot utility'
|
|
'i3status: Status line'
|
|
'mako: Lightweight notification daemon'
|
|
'slurp: Select a region'
|
|
'swayidle: Idle management daemon'
|
|
'swaylock: Screen locker'
|
|
'wallutils: Timed wallpapers'
|
|
'waybar: Highly customizable bar'
|
|
'xorg-xwayland: X11 support'
|
|
)
|
|
source=("https://github.com/swaywm/sway/releases/download/$pkgver/sway-$pkgver.tar.gz"
|
|
"https://github.com/swaywm/sway/releases/download/$pkgver/sway-$pkgver.tar.gz.sig"
|
|
"50-systemd-user.conf")
|
|
sha512sums=('7f37fea99970db42c5485277df06d69bef5225fa03d25be179893b14d73c1d681f0355a1bc74091b4173bbccc88994a63ad0f9322e070811ba963648cf68cdeb'
|
|
'SKIP'
|
|
'c2b7d808f4231f318e03789015624fd4cf32b81434b15406570b4e144c0defc54e216d881447e6fd9fc18d7da608cccb61c32e0e1fab2f1fe2750acf812d3137')
|
|
validpgpkeys=('34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48' # Simon Ser
|
|
'9DDA3B9FA5D58DD5392C78E652CB6609B22DA89A') # Drew DeVault
|
|
|
|
prepare() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
# Set the version information to 'Arch Linux' instead of 'makepkg'
|
|
sed -i "s/branch \\\'@1@\\\'/Arch Linux/g" meson.build
|
|
}
|
|
|
|
build() {
|
|
mkdir -p build
|
|
arch-meson build "$pkgname-$pkgver" -D sd-bus-provider=libsystemd -D werror=false -D b_ndebug=true
|
|
ninja -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" ninja -C build install
|
|
install -Dm644 "$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
install -Dm644 50-systemd-user.conf -t "$pkgdir/etc/sway/config.d/"
|
|
|
|
for util in autoname-workspaces.py inactive-windows-transparency.py grimshot; do
|
|
install -Dm755 "$pkgname-$pkgver/contrib/$util" -t \
|
|
"$pkgdir/usr/share/$pkgname/scripts"
|
|
done
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et
|