You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
62 lines
2.2 KiB
Bash
62 lines
2.2 KiB
Bash
# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
|
|
# Maintainer: Brett Cornwall <ainola@archlinux.org>
|
|
|
|
pkgname=sway
|
|
pkgver=1.4
|
|
epoch=1
|
|
pkgrel=6
|
|
pkgdesc='Tiling Wayland compositor and replacement for the i3 window manager'
|
|
arch=(x86_64)
|
|
url='https://swaywm.org/'
|
|
license=(MIT)
|
|
depends=(cairo gdk-pixbuf2 json-c pango pcre swaybg ttf-font wlroots)
|
|
makedepends=(git meson ninja scdoc setconf wayland-protocols)
|
|
backup=(etc/sway/config)
|
|
optdepends=(
|
|
'alacritty: Terminal emulator used by the default config'
|
|
'dmenu: Application launcher'
|
|
'grim: Screenshot utility'
|
|
'i3status: Status line'
|
|
'mako: Lightweight notification daemon'
|
|
'slurp: Select a region'
|
|
'swaybg: Wallpaper tool for Wayland compositors'
|
|
'swayidle: Idle management daemon'
|
|
'swaylock: Screen locker'
|
|
'wallutils: Timed wallpapers'
|
|
'waybar: Highly customizable bar'
|
|
'xorg-server-xwayland: X11 support'
|
|
)
|
|
source=("https://github.com/swaywm/sway/releases/download/$pkgver/sway-$pkgver.tar.gz"
|
|
"https://github.com/swaywm/sway/releases/download/$pkgver/sway-$pkgver.tar.gz.sig"
|
|
"50-systemd-user.conf")
|
|
sha512sums=('3b280bdfdbdae8fb9b4f555bc630c64e7c1d09f7b2c783b99413863a6b620d50cd2b6d10d63e11fdfb9c678fce9a403228ac52fa69fb52561ffbd06790505a71'
|
|
'SKIP'
|
|
'57590bc0d14c87289a4a9cd67991c6a841e54244d2a6186b5da5a08e633de2e8631959fa8c77ede211b0a5f315d920f2c1350951a53d6f2e9e81859056cb3c9e')
|
|
validpgpkeys=('9DDA3B9FA5D58DD5392C78E652CB6609B22DA89A') # Drew DeVault
|
|
|
|
prepare() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
# Set the version information to 'Arch Linux' instead of 'makepkg'
|
|
sed -i "s/branch \\\'@1@\\\'/Arch Linux/g" meson.build
|
|
}
|
|
|
|
build() {
|
|
mkdir -p build
|
|
arch-meson build "$pkgname-$pkgver" -D werror=false -D b_ndebug=true
|
|
ninja -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" ninja -C build install
|
|
install -Dm644 "$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
install -Dm644 50-systemd-user.conf -t "$pkgdir/etc/sway/config.d/"
|
|
|
|
for util in autoname-workspaces.py inactive-windows-transparency.py grimshot; do
|
|
install -Dm755 "$pkgname-$pkgver/contrib/$util" -t \
|
|
"$pkgdir/usr/share/$pkgname/scripts"
|
|
done
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et
|